81b9b1ef90a4ea61939948aa9fbce5fdcfc726d9
[buildd-scripts.git] / bin / analyze_results
1 #! /usr/bin/perl
2 #
3 # analyze_results
4 #
5 # Script to analyze failed build logs. Look for specific regexps to
6 # classify things
7 #
8 #
9 # (c) 2018 Steve McIntyre <steve@einval.com> GPL v2+
10
11 use strict;
12 use warnings;
13 use POSIX qw(strftime);
14 use Data::Dumper;
15
16 my $name = "analyze_results";
17 my $repo = "https://git.einval.com/cgi-bin/gitweb.cgi?p=buildd-scripts.git";
18 my $hostname;
19 my $date;
20 my $time_start = time();
21 my $time_end;
22 my $time_taken;
23 my $num_fail = 0;
24 my $lines_read = 0;
25 my $existing_bugs = 0;
26
27 use constant {
28     ERR_ARCH_MISMATCH      => 1,
29     ERR_INFRA              => 2,
30     ERR_BD_PROBLEM         => 3,
31     ERR_DETECT_WRONG_ARCH  => 4,
32     ERR_CRASH              => 5,
33     ERR_BUILD_PROBLEM      => 6,
34     ERR_TEST_PROBLEM       => 7,
35     ERR_BUILD_TIMEOUT      => 8,
36 };
37
38 my @err_descriptions;
39 $err_descriptions [ERR_ARCH_MISMATCH]     = "Architecture mismatches";
40 $err_descriptions [ERR_INFRA]             = "Infrastructure errors";
41 $err_descriptions [ERR_BD_PROBLEM]        = "Problems with build-deps";
42 $err_descriptions [ERR_DETECT_WRONG_ARCH] = "Builds detected wrong architecture";
43 $err_descriptions [ERR_CRASH]             = "Crashes detected";
44 $err_descriptions [ERR_BUILD_PROBLEM]     = "Problems detected during build phase";
45 $err_descriptions [ERR_TEST_PROBLEM]      = "Problems detected during test phase";
46 $err_descriptions [ERR_BUILD_TIMEOUT]     = "Package builds timed out";
47
48 # Known failure modes to look for
49 my @logcheck = (
50     {
51         # "rchitecture mismatch" -> should never build on this arch
52         # Stop working on this log at this point
53         string   => 'rchitecture mismatch',
54         message  => 'Architecture mismatch',
55         check    => 1,
56         stop     => 1,
57         type     => ERR_ARCH_MISMATCH,
58     },
59     {
60         string   => 'not in arch list or does not match any',
61         message  => 'Architecture mismatch',
62         check    => 1,
63         stop     => 1,
64         type     => ERR_ARCH_MISMATCH,
65     },
66     {
67         # "binary build with no binary artifacts found" -> no packages
68         # built. Why not picked up already above?.
69         # Stop working on this log at this point
70         string   => 'binary build with no binary artifacts found',
71         message  => 'No binaries built',
72         check    => 1,
73         stop     => 1,
74         type     => ERR_ARCH_MISMATCH,
75     },
76     {
77         string   => 'schroot.*File is not owned by user root',
78         message  => 'Schroot setup failure',
79         check    => 1,
80         stop     => 1,
81         type     => ERR_INFRA,
82     },
83     {
84         string   => 'No space left on device',
85         message  => 'Build ran out of disk space',
86         check    => 1,
87         stop     => 1,
88         type     => ERR_INFRA,
89     },
90     {
91         string   => 'aarch64-unknown-linux-gnu',
92         message  => 'Wrong arch detected',
93         check    => 1,
94         stop     => 1,
95         type     => ERR_DETECT_WRONG_ARCH,
96     },
97     {
98         string   => 'binutils-aarch64',
99         message  => 'Wrong arch detected',
100         check    => 0,
101         stop     => 1,
102         type     => ERR_DETECT_WRONG_ARCH,
103     },
104     {
105         string   => 'lib.linux-aarch64',
106         message  => 'Wrong arch detected',
107         check    => 1,
108         stop     => 1,
109         type     => ERR_DETECT_WRONG_ARCH,
110     },
111     {
112         # "Bus error" -> alignment bug
113         string   => 'Bus error',
114         message  => 'Alignment problem',
115         check    => 1,
116         stop     => 1,
117         type     => ERR_CRASH,
118     },
119     {
120         # "Segmentation fault" -> code problem
121         string   => 'Segmentation fault',
122         pstring  => 'Setting up (\S+)',
123         message  => 'Segmentation fault when installing RESULT',
124         check    => 1,
125         stop     => 1,
126         type     => ERR_CRASH,
127     },
128     {
129         # "Segmentation fault" -> code problem
130         string   => 'Segmentation fault',
131         message  => 'Segmentation fault',
132         check    => 1,
133         stop     => 1,
134         type     => ERR_CRASH,
135     },
136     {
137         # "Illegal instruction" -> bad build target?
138         string   => 'Illegal instruction',
139         pstring  => 'Setting up (\S+)',
140         message  => 'Illegal instruction when installing RESULT',
141         check    => 1,
142         stop     => 1,
143         type     => ERR_CRASH,
144     },
145     {
146         # "Illegal instruction" -> bad build target?
147         string   => 'Illegal instruction',
148         message  => 'Illegal instruction',
149         check    => 1,
150         stop     => 1,
151         type     => ERR_CRASH,
152     },
153     {
154         # Installing build-deps failed
155         string   => 'dpkg: error processing package (\S+)',
156         message  => 'Build-dep failed to install (RESULT)',
157         check    => 1,
158         stop     => 0,
159         type     => ERR_BD_PROBLEM,
160     },
161     {
162         # Installing build-deps failed
163         string   => 'E: pbuilder-satisfydepends failed.',
164         message  => 'Pbuilder build-deps failed',
165         check    => 1,
166         stop     => 1,
167         type     => ERR_BD_PROBLEM,
168     },
169     {
170         # Installing build-deps failed
171         string   => 'E: Unmet dependencies',
172         message  => 'Build-deps failed',
173         check    => 1,
174         stop     => 1,
175         type     => ERR_BD_PROBLEM,
176     },
177     {
178         # Installing build-deps failed
179         string   => 'unsat-dependency: (\S+)',
180         message  => 'Missing build-dep (RESULT)',
181         check    => 1,
182         stop     => 1,
183         type     => ERR_BD_PROBLEM,
184     },
185     {
186         # Build failed - missing build-dep?
187         string   => 'build dependencies/conflicts unsatisfied',
188         message  => 'Build-deps not satisfiable',
189         check    => 1,
190         stop     => 1,
191         type     => ERR_BD_PROBLEM,
192     },
193     {
194         # Build failed - missing build-dep?
195         string   => 'ld: cannot find',
196         message  => 'Build failure: missing library - missing build-dep?',
197         check    => 1,
198         stop     => 1,
199         type     => ERR_BUILD_PROBLEM,
200     },
201     {
202         # Build failed - missing build-dep?
203         string   => 'fatal error:.*No such file or directory',
204         message  => 'Build failure: missing header - missing build-dep?',
205         check    => 1,
206         stop     => 1,
207         type     => ERR_BUILD_PROBLEM,
208     },
209     {
210         # Build failed - missing build-dep?
211         string   => 'SEVERE: Cannot resolve dependencies',
212         message  => 'Build failure - missing build-dep?',
213         check    => 1,
214         stop     => 1,
215         type     => ERR_BUILD_PROBLEM,
216     },
217     {
218         # Build failed - can't exec something...
219         string   => 'error trying to exec.*execvp: No',
220         message  => 'Build failure (missing binary)',
221         check    => 1,
222         stop     => 1,
223         type     => ERR_BUILD_PROBLEM,
224     },
225     {
226         # Build failed
227         string   => 'BUILD FAILED',
228         message  => 'Build failure (java/javadoc)',
229         check    => 1,
230         stop     => 1,
231         type     => ERR_BUILD_PROBLEM,
232     },
233     {
234         # Build failed
235         string   => 'make.*returned exit code',
236         message  => 'Build failure (other)',
237         check    => 1,
238         stop     => 0,
239         type     => ERR_BUILD_PROBLEM,
240     },
241     {
242         # Build failed
243         string   => '^make.*\*\*\*.* \[debian/rules.*Error \d+$',
244         message  => 'Build failure (other)',
245         check    => 1,
246         stop     => 0,
247         type     => ERR_BUILD_PROBLEM,
248     },
249     {
250         # Build failed
251         string   => 'dpkg-source: error: unrepresentable changes to source',
252         message  => 'dpkg-source failure',
253         check    => 1,
254         stop     => 1,
255         type     => ERR_BUILD_PROBLEM,
256     },
257     {
258         # Build failed
259         string   => 'fakeroot debian/rules binary',
260         message  => 'Build failure (other)',
261         check    => 0,
262         stop     => 1,
263         type     => ERR_BUILD_PROBLEM,
264     },
265     {
266         # Test failure
267         string   => 'OSError: \[Errno 13\] Permission denied',
268         message  => 'Python EPERM test failure',
269         check    => 1,
270         stop     => 1,
271         type     => ERR_TEST_PROBLEM,
272     },
273     {
274         # Test failure
275         string   => 'dh_auto_test:.*returned exit code \d+',
276         message  => 'Test failure',
277         check    => 1,
278         stop     => 1,
279         type     => ERR_TEST_PROBLEM,
280     },
281     {
282         # Timeout. pbuilder is too dumb to do this properly :-(
283         string   => 'I: Terminating build process due to timeout',
284         message  => 'Pbuilder build timeout',
285         check    => 1,
286         stop     => 1,
287         type     => ERR_BUILD_TIMEOUT,
288     },
289     {
290         # Timeout from sbuild
291         string   => 'Build killed with signal TERM after \d+ minutes of inactivity',
292         message  => 'Sbuild build timeout',
293         check    => 1,
294         stop     => 1,
295         type     => ERR_BUILD_TIMEOUT,
296     },
297 );
298
299 my %log_results;
300
301 #foreach my $checktmp (@logcheck) {
302 #    my %check = %$checktmp;
303 #    print "looking for \"$check{string}\"\n";
304 #    print "  with log message \"$check{message}\"\n";
305 #    print "  check this regexp: $check{check}\n";
306 #    print "  stop if found: $check{stop}\n";
307 #}
308
309 print "<html>\n";
310 print "<head>\n";
311 print "<title>Build log analysis</title>\n";
312 print "</head>\n";
313 print "<body>\n";
314 print "<h1>Build log analysis</h1>\n";
315 print "<p><a href=\"#summary\">Summary</a></p>\n";
316 print "<h2>Packages</h2>\n";
317 print "<ol>\n";
318
319 foreach my $input (@ARGV) {
320     open (IN, "< $input") or die "Can't read $input: $!\n";
321     $num_fail++;
322     my $stop = 0;
323     my $lineno = 0;
324     my $errors = 0;
325     my $oldline = "";
326     my %file_results;
327     print "<li>Looking at <a href=\"$input\">$input</a>:\n";
328     print "<ul>\n";
329     while (defined (my $line = <IN>) and !$stop) {
330         $lineno++;
331         $lines_read++;
332         foreach my $checktmp (@logcheck) {
333             my %check = %$checktmp;
334             if ($check{check}) {
335                 if (!$stop
336                     and ($line =~ m/$check{string}/)
337                     and (!$check{pstring} or $oldline =~ m/$check{pstring}/)) {
338 #                   print "  Line $lineno: found \"$check{string}\"\n";
339                     my $match = $1;
340                     my $message = $check{message};
341                     $message =~ s,RESULT,$match,g;
342                     $file_results{$message} = $check{type};
343                     if ($check{type} == ERR_BUILD_TIMEOUT and $errors == 0) {
344                         print "  <li>Line $lineno: $message\n";
345                         print "  <li>Build killed by timeout before any errors at line $lineno\n";
346                     } else {
347                         print "  <li>Line $lineno: $message\n";
348                         $errors++;
349                     }
350                     if ($check{stop}) {
351 #                       print "  stopping processing\n";
352                         $stop = 1;
353                     }
354                 }
355             }
356         }
357         $oldline = $line;
358     }
359     close IN;
360     # End of checking this package
361     print "  <li><strong>Found errors: $errors</strong>\n";
362     if (!$errors) {
363         print " (maybe just timed out during build?)\n";
364     }
365
366     # Look for a note for manually-added logfile analysis
367     my $note = $input;
368     $note =~ s,\.log$,.note,;
369     if (-f $note) {
370         open (IN, "< $note") or die "Can't open $note for reading: $!\n";
371         while (defined (my $line = <IN>)) {
372             chomp $line;
373             if ($line =~ m,#(\d+),) {
374                 my $bugno = $1;
375                 $existing_bugs++;
376                 $line =~ s,#(\d+),<a href="https://bugs.debian.org/$1">#$1</a>,g;
377             }
378             print "  <li>$line\n";
379         }
380         close IN;
381     }
382
383     print "</ul>\n";
384     foreach my $key (keys %file_results) {
385         $log_results{$file_results{$key}}{$key} += 1;
386 #       print "now have $log_results{$key} for \"$key\"\n";
387     }
388 }
389 print "</ol>\n";
390
391 print "<a name=\"summary\"</a>\n";
392 print "<h2>Summary of results from $num_fail failed builds:</h2>\n";
393 print "<ul>\n";
394 print "<li>  Found $existing_bugs existing bugs in the Debian BTS</li>\n";
395 foreach my $type (sort keys %log_results) {
396     print "  <h3>$err_descriptions[$type]</h3>\n";
397     my $tmp = $log_results{$type};
398     my %result = %$tmp;
399     foreach my $key (sort { $result{$b} <=> $result{$a} }keys %result) {
400         print "  <li>Found $result{$key} log(s) showing $key\n";
401     }
402 }
403 print "</ul>\n";
404
405 $time_end = time();
406 $time_taken = $time_end - $time_start;
407 $date = strftime "%a %b %e %H:%M:%S %Z %Y", localtime;
408 $hostname = `hostname`;
409
410 print "<hr>\n";
411 print "<p>Log analysis generated on $hostname, $date.\n";
412 print "<br>Output from $name - see <a href=\"$repo\">$repo</a> for source.\n";
413 print "<br>Read $lines_read lines of logs and took $time_taken seconds to complete.\n";
414
415 print "</body>\n";
416 print "</html>\n";