abcde-musicbrainz-tool

   1 #!/usr/bin/perl
   2 # Copyright (c) 2012-2016 Steve McIntyre <93sam@debian.org>
   3 # This code is hereby licensed for public consumption under either the
   4 # GNU GPL v2 or greater, or Larry Wall's Artistic license - your choice.
   5 #
   6 # You should have received a copy of the GNU General Public License along
   7 # with this program; if not, write to the Free Software Foundation, Inc.,
   8 # 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
   9 #
  10 # abcde-musicbrainz-tool
  11 #
  12 # Helper script for abcde to work with the MusicBrainz WS API (v2)
  13
  14 use strict;
  15 use utf8;
  16 use POSIX qw(ceil);
  17 use Digest::SHA;
  18 use MusicBrainz::DiscID;
  19 use WebService::MusicBrainz::Release;
  20 use WebService::MusicBrainz::Artist;
  21 use WebService::MusicBrainz::Response::Track;
  22 use WebService::MusicBrainz::Response::TrackList;
  23 use Getopt::Long;
  24 use Pod::Usage;
  25
  26 my $FRAMES_PER_S = 75;
  27
  28 my ($device, $command, $discid, @discinfo, $workdir, $help, $man, $start);
  29 Getopt::Long::Configure ('no_ignore_case');
  30 Getopt::Long::Configure ('no_auto_abbrev');
  31 GetOptions ("device=s"       => \$device,
  32             "command=s"      => \$command,
  33             "discid=s"       => \$discid,
  34             "discinfo=i{5,}" => \@discinfo,
  35             "workdir=s"      => \$workdir,
  36             "workdir=s"      => \$workdir,
  37             "start=s"        => \$start,
  38             "help|h"         => \$help,
  39             "man"            => \$man) or pod2usage(-verbose => 0, -exitcode => 2);
  40 if (@ARGV) {
  41     print STDERR "Extraneous arguments given.\n";
  42     pod2usage(-verbose => 0, -exitcode => 2);
  43 }
  44 pod2usage(-verbose => 1, -exitcode => 0) if $help;
  45 pod2usage(-verbose => 2, -exitcode => 0) if $man;
  46
  47 # defaults
  48 if (!defined($device)) {
  49     $device = "/dev/cdrom";
  50 }
  51 if (!defined($command)) {
  52     $command = "id";
  53 }
  54 if (!defined($workdir)) {
  55     $workdir = "/tmp";
  56 }
  57 if (!defined($start)) {
  58     $start = "0";
  59 }
  60
  61 sub calc_sha1($) {
  62     my $filename = shift;
  63     my $s = Digest::SHA->new(1);
  64     $s->addfile($filename);
  65     return $s->hexdigest;
  66 }
  67
  68 if ($command =~ m/^id/) {
  69     my $disc = new MusicBrainz::DiscID($device);
  70
  71     # read the disc in the default disc drive */
  72     if ( $disc->read() == 0 ) {
  73         printf STDERR "Error: %s\n", $disc->error_msg();
  74         exit(1);
  75     }
  76
  77     printf("%s ", $disc->id());
  78     printf("%d ", $disc->last_track_num() + 1 - $disc->first_track_num());
  79
  80     for ( my $i = $disc->first_track_num;
  81           $i <= $disc->last_track_num; $i++ ) {
  82         printf("%d ", $disc->track_offset($i));
  83     }
  84     printf("%d\n", $disc->sectors() / $FRAMES_PER_S);
  85     undef $disc;
  86 } elsif ($command =~ m/data/) {
  87     if (!defined $discid or !$discid) {
  88         print STDERR "Discid undefined.\n";
  89         exit(1);
  90     }
  91     my $ws = WebService::MusicBrainz::Release->new();
  92     my $response = $ws->search({ DISCID => $discid });
  93     my @releases = $response->release_list();
  94     my $releasenum = $start;
  95     my @sums;
  96
  97     foreach my $release (@releases) {
  98         my $a_artist = $release->artist()->name();
  99         my $va = 0;
 100         my $rel_year = "";
 101         if ($a_artist =~ /Various Artists/) {
 102             $va = 1;
 103         }
 104         my $release_event_list = $release->release_event_list();
 105         if ($release_event_list) {
 106             my @events = @{$release->release_event_list()->events()};
 107             $rel_year =  substr($events[0]->date(),0,4);
 108         }
 109
 110         $releasenum++;
 111         open (OUT, "> $workdir/cddbread.$releasenum");
 112         binmode OUT, ":utf8";
 113         print OUT "# xmcd style database file\n";
 114         print OUT "#\n";
 115         print OUT "# Track frame offsets:\n";
 116         # Assume standard pregap
 117         my $total_len = 2000;
 118         my @tracks = @{$release->track_list()->tracks()};
 119         for (my $i = 0; $i < scalar(@tracks); $i++) {
 120             printf OUT "#       %d\n", ceil($total_len * $FRAMES_PER_S / 1000.0);
 121             $total_len += $tracks[$i]->duration();
 122         }
 123         print OUT "#\n";
 124         printf OUT "# Disc length: %d seconds\n", $total_len / 1000.0;
 125         print OUT "#\n";
 126         print OUT "# Submitted via: XXXXXX\n";
 127         print OUT "#\n";
 128         print OUT "#blues,classical,country,data,folk,jazz,newage,reggae,rock,soundtrack,misc\n";
 129         print OUT "#CATEGORY=none\n";
 130         print OUT "DISCID=" . $discid . "\n";
 131         print OUT "DTITLE=" . $a_artist. " / " . $release->title() . "\n";
 132         print OUT "DYEAR=" . $rel_year . "\n";
 133         print OUT "DGENRE=\n";
 134
 135         my @tracks = @{$release->track_list()->tracks()};
 136         for (my $i = 0; $i < scalar(@tracks); $i++) {
 137             my $track = $tracks[$i];
 138             my $t_name = $track->title;
 139             if ($va) {
 140                 my $t_artist = $track->artist->name;
 141                 printf OUT "TTITLE%d=%s / %s\n", $i, $t_artist, $t_name;
 142             } else {
 143                 printf OUT "TTITLE%d=%s\n", $i, $t_name;
 144             }
 145         }
 146
 147         print OUT "EXTD=\n";
 148         for (my $i = 0; $i < scalar(@tracks); $i++) {
 149             printf OUT "EXTT%d=\n", $i;
 150         }
 151         print OUT "PLAYORDER=\n";
 152         print OUT ".\n";
 153         close OUT;
 154
 155         # save release mbid
 156         open (OUT, "> $workdir/mbid.$releasenum");
 157         print OUT $release->id;
 158         close OUT;
 159
 160         # save release asin
 161         open (OUT, "> $workdir/asin.$releasenum");
 162         print OUT $release->asin;
 163         close OUT;
 164
 165         # Check to see that this entry is unique; generate a checksum
 166         # and compare to any previous checksums
 167         my $checksum = calc_sha1("$workdir/cddbread.$releasenum");
 168         foreach my $sum (@sums) {
 169             if ($checksum eq $sum) {
 170                 unlink("$workdir/cddbread.$releasenum");
 171                 $releasenum--;
 172                 last;
 173             }
 174         }
 175         push (@sums, $checksum);
 176     }
 177 } elsif ($command =~ m/calcid/) {
 178 # Calculate MusicBrainz ID from disc offsets; see
 179 # https://musicbrainz.org/doc/DiscIDCalculation
 180
 181
 182     if ($#discinfo < 5) {
 183         print STDERR "Insufficient or missing discinfo data.\n";
 184         exit(1);
 185     }
 186     my ($first, $last, $leadin, $leadout, @offsets) = @discinfo;
 187
 188     my $s = Digest::SHA->new(1);
 189     $s->add(sprintf "%02X", int($first));
 190     $s->add(sprintf "%02X", int($last));
 191
 192     my @a;
 193     for (my $i = 0; $i < 100; $i++) {
 194         $a[$i] = 0;
 195     }
 196     my $i = 0;
 197     foreach my $o ($leadout, @offsets) {
 198        $a[$i++] = int($o) + int($leadin);
 199     }
 200     for (my $i = 0; $i < 100; $i++) {
 201        $s->add(sprintf "%08X", $a[$i]);
 202     }
 203
 204     my $id = $s->b64digest;
 205     # CPAN Digest modules do not pad their Base64 output, so we have to do it.
 206     while (length($id) % 4) {
 207         $id .= '=';
 208     }
 209
 210     $id =~ tr#+#.#;
 211     $id =~ tr#/#_#;
 212     $id =~ tr#=#-#;
 213
 214     print $id;
 215     if (-t STDOUT) { print "\n"; }
 216 } else {
 217     print STDERR "Unknown command given.\n";
 218     pod2usage(1);
 219     exit(1);
 220 }
 221 __END__
 222
 223 =head1 NAME
 224
 225 abcde-musicbrainz-tool - Musicbrainz query tool
 226
 227 =head1 SYNOPSIS
 228
 229  abcde-musicbrainz-tool [options]
 230
 231  Options:
 232    --command {id|data|calcid} mode of operation (default: id)
 233    --device <DEV>             read from CD-ROM device DEV (default: /dev/cdrom)
 234    --discid <ID>              Disc ID to query with --command data.
 235    --discinfo <F> <L> <LI> <LO> <TRK1OFF> [<TRK2OFF> [...]]
 236                               Disc information for --command calcid.
 237    --workdir <DIR>            working directory (default: /tmp)
 238    --help                     print option summary
 239    --man                      full documentation
 240
 241 =head1 OPTIONS
 242
 243 =over 8
 244
 245 =item B<--command> I<{id|data|calcid}>
 246
 247 Select mode of operation:
 248
 249 =over 8
 250
 251 =item B<id>
 252
 253 Read the disc-ID from the disc in the given device, and print it, the number of tracks, their start sectors, and the duration of the disc in seconds, to stdout. Format:
 254
 255  ID TRACKCOUNT OFFSET1 [OFFSET2 [...]] LENGTH_S
 256
 257 =item B<data>
 258
 259 Query MusicBrainz web service and store data into the workdir into cddbread.1, cddbread.2, ... files in the workdir.
 260
 261 =item B<calcid>
 262
 263 Calculate MusicBrainz ID from given B<--discinfo> data.
 264
 265 =back
 266
 267 =item B<--device>
 268
 269 Specify CD-ROM drive's device name, to read ID from with B<--command id>.
 270
 271 =item B<--discid>
 272
 273 Supply disc ID for B<--command data>.
 274
 275 =item B<--discinfo> I<<first track> <last track> <lead-in sector> <lead-out sector> <track1 offset> [<track2 offset> [...]]>
 276
 277 Supply disc information for B<--command calcid>.
 278
 279 =item B<--workdir> I<directory>
 280
 281 The cddbread.* output files from B<--command data> go into this directory.
 282
 283 =item B<--help>
 284
 285 Print a brief help message and exit.
 286
 287 =item B<--man>
 288
 289 Display full manual and exit.
 290
 291 =back