abcde-musicbrainz-tool

   1 #!/usr/bin/perl
   2 # Copyright (c) 2012-2018 Steve McIntyre <93sam@debian.org>
   3 # This code is hereby licensed for public consumption under either the
   4 # GNU GPL v2 or greater, or Larry Wall's Artistic license - your choice.
   5 #
   6 # You should have received a copy of the GNU General Public License along
   7 # with this program; if not, write to the Free Software Foundation, Inc.,
   8 # 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
   9 #
  10 # abcde-musicbrainz-tool
  11 #
  12 # Helper script for abcde to work with the MusicBrainz WS API (v2)
  13
  14 use strict;
  15 use utf8;
  16 use POSIX qw(ceil);
  17 use Digest::SHA;
  18 use MusicBrainz::DiscID;
  19 use WebService::MusicBrainz::Release;
  20 use WebService::MusicBrainz::Artist;
  21 use WebService::MusicBrainz::Response::Track;
  22 use WebService::MusicBrainz::Response::TrackList;
  23 use Getopt::Long;
  24 use Pod::Usage;
  25
  26 my $FRAMES_PER_S = 75;
  27
  28 my ($device, $command, $discid, @discinfo, $workdir, $help, $man, $start);
  29 Getopt::Long::Configure ('no_ignore_case');
  30 Getopt::Long::Configure ('no_auto_abbrev');
  31 GetOptions ("device=s"       => \$device,
  32             "command=s"      => \$command,
  33             "discid=s"       => \$discid,
  34             "discinfo=i{5,}" => \@discinfo,
  35             "workdir=s"      => \$workdir,
  36             "start=s"        => \$start,
  37             "help|h"         => \$help,
  38             "man"            => \$man) or pod2usage(-verbose => 0, -exitcode => 2);
  39 if (@ARGV) {
  40     print STDERR "Extraneous arguments given.\n";
  41     pod2usage(-verbose => 0, -exitcode => 2);
  42 }
  43 pod2usage(-verbose => 1, -exitcode => 0) if $help;
  44 pod2usage(-verbose => 2, -exitcode => 0) if $man;
  45
  46 # defaults
  47 if (!defined($device)) {
  48     $device = "/dev/cdrom";
  49 }
  50 if (!defined($command)) {
  51     $command = "id";
  52 }
  53 if (!defined($workdir)) {
  54     $workdir = "/tmp";
  55 }
  56 if (!defined($start)) {
  57     $start = "0";
  58 }
  59
  60 sub calc_sha1($) {
  61     my $filename = shift;
  62     my $s = Digest::SHA->new(1);
  63     $s->addfile($filename);
  64     return $s->hexdigest;
  65 }
  66
  67 if ($command =~ m/^id/) {
  68     my $disc = new MusicBrainz::DiscID($device);
  69
  70     # read the disc in the default disc drive */
  71     if ( $disc->read() == 0 ) {
  72         printf STDERR "Error: %s\n", $disc->error_msg();
  73         exit(1);
  74     }
  75
  76     printf("%s ", $disc->id());
  77     printf("%d ", $disc->last_track_num() + 1 - $disc->first_track_num());
  78
  79     for ( my $i = $disc->first_track_num;
  80           $i <= $disc->last_track_num; $i++ ) {
  81         printf("%d ", $disc->track_offset($i));
  82     }
  83     printf("%d\n", $disc->sectors() / $FRAMES_PER_S);
  84     undef $disc;
  85 } elsif ($command =~ m/data/) {
  86     if (!defined $discid or !$discid) {
  87         print STDERR "Discid undefined.\n";
  88         exit(1);
  89     }
  90     my $ws = WebService::MusicBrainz::Release->new();
  91     my $response = $ws->search({ DISCID => $discid });
  92     my @releases = $response->release_list();
  93     my $releasenum = $start;
  94     my @sums;
  95
  96     foreach my $release (@releases) {
  97         my $a_artist = $release->artist()->name();
  98         my $va = 0;
  99         my $rel_year = "";
 100         if ($a_artist =~ /Various Artists/) {
 101             $va = 1;
 102         }
 103         my $release_event_list = $release->release_event_list();
 104         if ($release_event_list) {
 105             my @events = @{$release->release_event_list()->events()};
 106             $rel_year =  substr($events[0]->date(),0,4);
 107         }
 108
 109         $releasenum++;
 110         open (OUT, "> $workdir/cddbread.$releasenum");
 111         binmode OUT, ":utf8";
 112         print OUT "# xmcd style database file\n";
 113         print OUT "#\n";
 114         print OUT "# Track frame offsets:\n";
 115         # Assume standard pregap
 116         my $total_len = 2000;
 117         my @tracks = @{$release->track_list()->tracks()};
 118         for (my $i = 0; $i < scalar(@tracks); $i++) {
 119             printf OUT "#       %d\n", ceil($total_len * $FRAMES_PER_S / 1000.0);
 120             $total_len += $tracks[$i]->duration();
 121         }
 122         print OUT "#\n";
 123         printf OUT "# Disc length: %d seconds\n", $total_len / 1000.0;
 124         print OUT "#\n";
 125         print OUT "# Submitted via: XXXXXX\n";
 126         print OUT "#\n";
 127         print OUT "#blues,classical,country,data,folk,jazz,newage,reggae,rock,soundtrack,misc\n";
 128         print OUT "#CATEGORY=none\n";
 129         print OUT "DISCID=" . $discid . "\n";
 130         print OUT "DTITLE=" . $a_artist. " / " . $release->title() . "\n";
 131         print OUT "DYEAR=" . $rel_year . "\n";
 132         print OUT "DGENRE=\n";
 133
 134         my @tracks = @{$release->track_list()->tracks()};
 135         for (my $i = 0; $i < scalar(@tracks); $i++) {
 136             my $track = $tracks[$i];
 137             my $t_name = $track->title;
 138             if ($va) {
 139                 my $t_artist = $track->artist->name;
 140                 printf OUT "TTITLE%d=%s / %s\n", $i, $t_artist, $t_name;
 141             } else {
 142                 printf OUT "TTITLE%d=%s\n", $i, $t_name;
 143             }
 144         }
 145
 146         print OUT "EXTD=\n";
 147         for (my $i = 0; $i < scalar(@tracks); $i++) {
 148             printf OUT "EXTT%d=\n", $i;
 149         }
 150         print OUT "PLAYORDER=\n";
 151         print OUT ".\n";
 152         close OUT;
 153
 154         # save release mbid
 155         open (OUT, "> $workdir/mbid.$releasenum");
 156         print OUT $release->id;
 157         close OUT;
 158
 159         # save release asin
 160         open (OUT, "> $workdir/asin.$releasenum");
 161         print OUT $release->asin;
 162         close OUT;
 163
 164         # Check to see that this entry is unique; generate a checksum
 165         # and compare to any previous checksums
 166         my $checksum = calc_sha1("$workdir/cddbread.$releasenum");
 167         foreach my $sum (@sums) {
 168             if ($checksum eq $sum) {
 169                 unlink("$workdir/cddbread.$releasenum");
 170                 $releasenum--;
 171                 last;
 172             }
 173         }
 174         push (@sums, $checksum);
 175     }
 176 } elsif ($command =~ m/calcid/) {
 177 # Calculate MusicBrainz ID from disc offsets; see
 178 # https://musicbrainz.org/doc/DiscIDCalculation
 179
 180
 181     if ($#discinfo < 5) {
 182         print STDERR "Insufficient or missing discinfo data.\n";
 183         exit(1);
 184     }
 185     my ($first, $last, $leadin, $leadout, @offsets) = @discinfo;
 186
 187     my $s = Digest::SHA->new(1);
 188     $s->add(sprintf "%02X", int($first));
 189     $s->add(sprintf "%02X", int($last));
 190
 191     my @a;
 192     for (my $i = 0; $i < 100; $i++) {
 193         $a[$i] = 0;
 194     }
 195     my $i = 0;
 196     foreach my $o ($leadout, @offsets) {
 197        $a[$i++] = int($o) + int($leadin);
 198     }
 199     for (my $i = 0; $i < 100; $i++) {
 200        $s->add(sprintf "%08X", $a[$i]);
 201     }
 202
 203     my $id = $s->b64digest;
 204     # CPAN Digest modules do not pad their Base64 output, so we have to do it.
 205     while (length($id) % 4) {
 206         $id .= '=';
 207     }
 208
 209     $id =~ tr#+#.#;
 210     $id =~ tr#/#_#;
 211     $id =~ tr#=#-#;
 212
 213     print $id;
 214     if (-t STDOUT) { print "\n"; }
 215 } else {
 216     print STDERR "Unknown command given.\n";
 217     pod2usage(1);
 218     exit(1);
 219 }
 220 __END__
 221
 222 =head1 NAME
 223
 224 abcde-musicbrainz-tool - Musicbrainz query tool
 225
 226 =head1 SYNOPSIS
 227
 228  abcde-musicbrainz-tool [options]
 229
 230  Options:
 231    --command {id|data|calcid} mode of operation (default: id)
 232    --device <DEV>             read from CD-ROM device DEV (default: /dev/cdrom)
 233    --discid <ID>              Disc ID to query with --command data.
 234    --discinfo <F> <L> <LI> <LO> <TRK1OFF> [<TRK2OFF> [...]]
 235                               Disc information for --command calcid.
 236    --workdir <DIR>            working directory (default: /tmp)
 237    --help                     print option summary
 238    --man                      full documentation
 239
 240 =head1 OPTIONS
 241
 242 =over 8
 243
 244 =item B<--command> I<{id|data|calcid}>
 245
 246 Select mode of operation:
 247
 248 =over 8
 249
 250 =item B<id>
 251
 252 Read the disc-ID from the disc in the given device, and print it, the number of tracks, their start sectors, and the duration of the disc in seconds, to stdout. Format:
 253
 254  ID TRACKCOUNT OFFSET1 [OFFSET2 [...]] LENGTH_S
 255
 256 =item B<data>
 257
 258 Query MusicBrainz web service and store data into the workdir into cddbread.1, cddbread.2, ... files in the workdir.
 259
 260 =item B<calcid>
 261
 262 Calculate MusicBrainz ID from given B<--discinfo> data.
 263
 264 =back
 265
 266 =item B<--device>
 267
 268 Specify CD-ROM drive's device name, to read ID from with B<--command id>.
 269
 270 =item B<--discid>
 271
 272 Supply disc ID for B<--command data>.
 273
 274 =item B<--discinfo> I<<first track> <last track> <lead-in sector> <lead-out sector> <track1 offset> [<track2 offset> [...]]>
 275
 276 Supply disc information for B<--command calcid>.
 277
 278 =item B<--workdir> I<directory>
 279
 280 The cddbread.* output files from B<--command data> go into this directory.
 281
 282 =item B<--help>
 283
 284 Print a brief help message and exit.
 285
 286 =item B<--man>
 287
 288 Display full manual and exit.
 289
 290 =back