Extend Musicbrainz multi-artist support
[abcde.git] / abcde-musicbrainz-tool
1 #!/usr/bin/perl
2 # Copyright (c) 2012-2018 Steve McIntyre <93sam@debian.org>
3 # This code is hereby licensed for public consumption under either the
4 # GNU GPL v2 or greater, or Larry Wall's Artistic license - your choice.
5 #
6 # You should have received a copy of the GNU General Public License along
7 # with this program; if not, write to the Free Software Foundation, Inc.,
8 # 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
9 #
10 # abcde-musicbrainz-tool
11 #
12 # Helper script for abcde to work with the MusicBrainz WS API (v2)
13
14 use strict;
15 use utf8;
16 use POSIX qw(ceil);
17 use Digest::SHA;
18 use MusicBrainz::DiscID;
19 use WebService::MusicBrainz 1.0.4;
20 use Getopt::Long;
21 use Pod::Usage;
22
23 my $FRAMES_PER_S = 75;
24
25 my ($device, $command, $discid, @discinfo, $workdir, $help, $man, $start);
26 Getopt::Long::Configure ('no_ignore_case');
27 Getopt::Long::Configure ('no_auto_abbrev');
28 GetOptions ("device=s"       => \$device,
29             "command=s"      => \$command,
30             "discid=s"       => \$discid,
31             "discinfo=i{5,}" => \@discinfo,
32             "workdir=s"      => \$workdir,
33             "start=s"        => \$start,
34             "help|h"         => \$help,
35             "man"            => \$man) or pod2usage(-verbose => 0, -exitcode => 2);
36 if (@ARGV) {
37     print STDERR "Extraneous arguments given.\n";
38     pod2usage(-verbose => 0, -exitcode => 2);
39 }
40 pod2usage(-verbose => 1, -exitcode => 0) if $help;
41 pod2usage(-verbose => 2, -exitcode => 0) if $man;
42
43 # defaults
44 if (!defined($device)) {
45     $device = "/dev/cdrom";
46 }
47 if (!defined($command)) {
48     $command = "id";
49 }
50 if (!defined($workdir)) {
51     $workdir = "/tmp";
52 }
53 if (!defined($start)) {
54     $start = "0";
55 }
56
57 sub calc_sha1($) {
58     my $filename = shift;
59     my $s = Digest::SHA->new(1);
60     $s->addfile($filename);
61     return $s->hexdigest;
62 }
63
64 if ($command =~ m/^id/) {
65     my $disc = new MusicBrainz::DiscID($device);
66
67     # read the disc in the default disc drive */
68     if ( $disc->read() == 0 ) {
69         printf STDERR "Error: %s\n", $disc->error_msg();
70         exit(1);
71     }
72
73     printf("%s ", $disc->id());
74     printf("%d ", $disc->last_track_num() + 1 - $disc->first_track_num());
75
76     for ( my $i = $disc->first_track_num;
77           $i <= $disc->last_track_num; $i++ ) {
78         printf("%d ", $disc->track_offset($i));
79     }
80     printf("%d\n", $disc->sectors() / $FRAMES_PER_S);
81     undef $disc;
82 } elsif ($command =~ m/data/) {
83     if (!defined $discid or !$discid) {
84         print STDERR "Discid undefined.\n";
85         exit(1);
86     }
87     my $ws = WebService::MusicBrainz->new();
88     my $response = $ws->search(discid => {
89         discid => $discid,
90         inc => ['artists', 'artist-credits', 'recordings']
91         });
92     my @releases = @{ $response->{'releases'} };
93     my $releasenum = $start;
94     my @sums;
95
96     foreach my $release (@releases) {
97         my $a_artist = "";
98         my $number_artists = @{ $release->{'artist-credit'}};
99         if ($number_artists > 0) {
100             for (my $i = 0; $i < $number_artists; $i++) {
101                 if ($i > 0) {
102                     $a_artist = $a_artist . @{ $release->{'artist-credit'} }[$i-1]->{'joinphrase'};
103                 }
104                 $a_artist = $a_artist . @{ $release->{'artist-credit'} }[$i]->{'name'};
105             }
106         }
107         my $va = 0;
108         my $rel_year = "";
109         if ($a_artist =~ /Various Artists/) {
110             $va = 1;
111         }
112
113         my @release_events = @{ $release->{'release-events'} };
114
115         if (@release_events > 0) {
116             $rel_year =  substr(@release_events[0]->{'date'},0,4);
117         }
118
119         $releasenum++;
120         open (OUT, "> $workdir/cddbread.$releasenum");
121         binmode OUT, ":utf8";
122         print OUT "# xmcd style database file\n";
123         print OUT "#\n";
124         print OUT "# Track frame offsets:\n";
125
126         my @offsets = @{ $response->{'offsets'}};
127         foreach my $offset (@offsets) {
128             printf OUT "#       %d\n", $offset;
129         }
130
131         # Locate the media that contains a disc with the discid we requested
132         # initially. The API may return multiple media associated with the
133         # release, including media with different discids
134         my @mediums = grep {
135             my @disks = @{ $_->{'discs'} };
136             grep { $_->{'id'} eq $discid } @disks;
137         } @{ $release->{'media'} };
138
139         if (not @mediums) {
140             # This release doesn't have a media with our requested dicsid
141             # Shouldn't happen (?), skip it
142             next;
143         }
144
145         # Only consider the first medium
146         my $medium = @mediums[0];
147         my @tracks = @{ $medium->{'tracks'} };
148
149         my $total_len = 0;
150         for (my $i = 0; $i < scalar(@tracks); $i++) {
151             my $track = $tracks[$i];
152             $total_len += $track->{'length'};
153         }
154
155         print OUT "#\n";
156         printf OUT "# Disc length: %d seconds\n", $total_len / 1000.0;
157         print OUT "#\n";
158         print OUT "# Submitted via: XXXXXX\n";
159         print OUT "#\n";
160         print OUT "#blues,classical,country,data,folk,jazz,newage,reggae,rock,soundtrack,misc\n";
161         print OUT "#CATEGORY=none\n";
162         print OUT "DISCID=" . $discid . "\n";
163         print OUT "DTITLE=" . $a_artist. " / " . $release->{'title'} . "\n";
164         print OUT "DYEAR=" . $rel_year . "\n";
165         print OUT "DGENRE=\n";        
166
167         for (my $i = 0; $i < scalar(@tracks); $i++) {
168             my $track = $tracks[$i];
169             my $t_name = $track->{'title'};
170             my $number_artists = @{$track->{'recording'}->{'artist-credit'}};
171             if ($va and $number_artists > 0) {
172                 my $t_artist = "";
173                 for (my $j = 0; $j < $number_artists; $j++) {
174                     if ($j > 0) {
175                         $t_artist = $t_artist . @{$track->{'recording'}->{'artist-credit'}}[$j-1]->{'joinphrase'};
176                     }
177                     $t_artist = $t_artist . @{$track->{'recording'}->{'artist-credit'}}[$j]->{'name'};
178                 }
179                 printf OUT "TTITLE%d=%s / %s\n", $i, $t_artist, $t_name;
180             } else {
181                 printf OUT "TTITLE%d=%s\n", $i, $t_name;
182             }
183         }
184
185         print OUT "EXTD=\n";
186         for (my $i = 0; $i < scalar(@tracks); $i++) {
187             printf OUT "EXTT%d=\n", $i;
188         }
189         print OUT "PLAYORDER=\n";
190         print OUT ".\n";
191         close OUT;
192
193         # save release mbid
194         open (OUT, "> $workdir/mbid.$releasenum");
195         print OUT $release->{'id'};
196         close OUT;
197
198         # save release asin
199         open (OUT, "> $workdir/asin.$releasenum");
200         print OUT $release->{'asin'};
201         close OUT;
202
203         # Check to see that this entry is unique; generate a checksum
204         # and compare to any previous checksums
205         my $checksum = calc_sha1("$workdir/cddbread.$releasenum");
206         foreach my $sum (@sums) {
207             if ($checksum eq $sum) {
208                 unlink("$workdir/cddbread.$releasenum");
209                 $releasenum--;
210                 last;
211             }
212         }
213         push (@sums, $checksum);
214     }
215 } elsif ($command =~ m/calcid/) {
216     # Calculate MusicBrainz ID from disc offsets; see
217     # https://musicbrainz.org/doc/DiscIDCalculation
218
219     if ($#discinfo < 5) {
220         print STDERR "Insufficient or missing discinfo data.\n";
221         exit(1);
222     }
223     my ($first, $last, $leadin, $leadout, @offsets) = @discinfo;
224
225     my $s = Digest::SHA->new(1);
226     $s->add(sprintf "%02X", int($first));
227     $s->add(sprintf "%02X", int($last));
228
229     my @a;
230     for (my $i = 0; $i < 100; $i++) {
231         $a[$i] = 0;
232     }
233     my $i = 0;
234     foreach my $o ($leadout, @offsets) {
235        $a[$i++] = int($o) + int($leadin);
236     }
237     for (my $i = 0; $i < 100; $i++) {
238        $s->add(sprintf "%08X", $a[$i]);
239     }
240
241     my $id = $s->b64digest;
242     # CPAN Digest modules do not pad their Base64 output, so we have to do it.
243     while (length($id) % 4) {
244         $id .= '=';
245     }
246
247     $id =~ tr#+#.#;
248     $id =~ tr#/#_#;
249     $id =~ tr#=#-#;
250
251     print $id;
252     if (-t STDOUT) { print "\n"; }
253 } else {
254     print STDERR "Unknown command given.\n";
255     pod2usage(1);
256     exit(1);
257 }
258 __END__
259
260 =head1 NAME
261
262 abcde-musicbrainz-tool - Musicbrainz query tool
263
264 =head1 SYNOPSIS
265
266  abcde-musicbrainz-tool [options]
267
268  Options:
269    --command {id|data|calcid} mode of operation (default: id)
270    --device <DEV>             read from CD-ROM device DEV (default: /dev/cdrom)
271    --discid <ID>              Disc ID to query with --command data.
272    --discinfo <F> <L> <LI> <LO> <TRK1OFF> [<TRK2OFF> [...]]
273                               Disc information for --command calcid.
274    --workdir <DIR>            working directory (default: /tmp)
275    --help                     print option summary
276    --man                      full documentation
277
278 =head1 OPTIONS
279
280 =over 8
281
282 =item B<--command> I<{id|data|calcid}>
283
284 Select mode of operation:
285
286 =over 8
287
288 =item B<id>
289
290 Read the disc-ID from the disc in the given device, and print it, the number of tracks, their start sectors, and the duration of the disc in seconds, to stdout. Format:
291
292  ID TRACKCOUNT OFFSET1 [OFFSET2 [...]] LENGTH_S
293
294 =item B<data>
295
296 Query MusicBrainz web service and store data into the workdir into cddbread.1, cddbread.2, ... files in the workdir.
297
298 =item B<calcid>
299
300 Calculate MusicBrainz ID from given B<--discinfo> data.
301
302 =back
303
304 =item B<--device>
305
306 Specify CD-ROM drive's device name, to read ID from with B<--command id>.
307
308 =item B<--discid>
309
310 Supply disc ID for B<--command data>.
311
312 =item B<--discinfo> I<<first track> <last track> <lead-in sector> <lead-out sector> <track1 offset> [<track2 offset> [...]]>
313
314 Supply disc information for B<--command calcid>.
315
316 =item B<--workdir> I<directory>
317
318 The cddbread.* output files from B<--command data> go into this directory.
319
320 =item B<--help>
321
322 Print a brief help message and exit.
323
324 =item B<--man>
325
326 Display full manual and exit.
327
328 =back