aadb56a7756871619d86f2d06c898ba485163320
[abcde.git] / abcde-musicbrainz-tool
1 #!/usr/bin/perl
2 # Copyright (c) 2012 Steve McIntyre <93sam@debian.org>
3 # This code is hereby licensed for public consumption under either the
4 # GNU GPL v2 or greater, or Larry Wall's Artistic license - your choice.
5 #
6 # You should have received a copy of the GNU General Public License along
7 # with this program; if not, write to the Free Software Foundation, Inc.,
8 # 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
9 #
10 # abcde-musicbrainz-tool
11 #
12 # Helper script for abcde to work with the MusicBrainz WS API (v2)
13
14 use strict;
15 use utf8;
16 use POSIX qw(ceil);
17 use Digest::SHA;
18 use MusicBrainz::DiscID;
19 use WebService::MusicBrainz::Release;
20 use WebService::MusicBrainz::Artist;
21 use WebService::MusicBrainz::Response::Track;
22 use WebService::MusicBrainz::Response::TrackList;
23 use Getopt::Long;
24 use Pod::Usage;
25
26 my $FRAMES_PER_S = 75;
27
28 my ($device, $command, $discid, @discinfo, $workdir, $help, $man);
29 Getopt::Long::Configure ('no_ignore_case');
30 Getopt::Long::Configure ('no_auto_abbrev');
31 GetOptions ("device=s"       => \$device,
32             "command=s"      => \$command,
33             "discid=s"       => \$discid,
34             "discinfo=i{5,}" => \@discinfo,
35             "workdir=s"      => \$workdir,
36             "help|h"         => \$help,
37             "man"            => \$man) or pod2usage(-verbose => 0, -exitcode => 2);
38 if (@ARGV) {
39     print STDERR "Extraneous arguments given.\n";
40     pod2usage(-verbose => 0, -exitcode => 2);
41 }
42 pod2usage(-verbose => 1, -exitcode => 0) if $help;
43 pod2usage(-verbose => 2, -exitcode => 0) if $man;
44
45 # defaults
46 if (!defined($device)) {
47     $device = "/dev/cdrom";
48 }
49 if (!defined($command)) {
50     $command = "id";
51 }
52 if (!defined($workdir)) {
53     $workdir = "/tmp";
54 }
55
56 sub calc_sha1($) {
57     my $filename = shift;
58     my $s = Digest::SHA->new(1);
59     $s->addfile($filename);
60     return $s->hexdigest;
61 }
62
63 if ($command =~ m/^id/) {
64     my $disc = new MusicBrainz::DiscID($device);
65
66     # read the disc in the default disc drive */
67     if ( $disc->read() == 0 ) {
68         printf STDERR "Error: %s\n", $disc->error_msg();
69         exit(1);
70     }
71
72     printf("%s ", $disc->id());
73     printf("%d ", $disc->last_track_num() + 1 - $disc->first_track_num());
74
75     for ( my $i = $disc->first_track_num;
76           $i <= $disc->last_track_num; $i++ ) {
77         printf("%d ", $disc->track_offset($i));
78     }
79     printf("%d\n", $disc->sectors() / $FRAMES_PER_S);
80     undef $disc;
81 } elsif ($command =~ m/data/) {
82     if (!defined $discid or !$discid) {
83         print STDERR "Discid undefined.\n";
84         exit(1);
85     }
86     my $ws = WebService::MusicBrainz::Release->new();
87     my $response = $ws->search({ DISCID => $discid });
88     my @releases = $response->release_list();
89     my $releasenum = 0;
90     my @sums;
91
92     foreach my $release (@releases) {
93         my $a_artist = $release->artist()->name();
94         my $va = 0;
95         if ($a_artist =~ /Various Artists/) {
96             $va = 1;
97         }
98         $releasenum++;
99         open (OUT, "> $workdir/cddbread.$releasenum");
100         binmode OUT, ":utf8";
101         print OUT "# xmcd style database file\n";
102         print OUT "#\n";
103         print OUT "# Track frame offsets:\n";
104         # Assume standard pregap
105         my $total_len = 2000;
106         my @tracks = @{$release->track_list()->tracks()};
107         for (my $i = 0; $i < scalar(@tracks); $i++) {
108             printf OUT "#       %d\n", ceil($total_len * $FRAMES_PER_S / 1000.0);
109             $total_len += $tracks[$i]->duration();
110         }
111         print OUT "#\n";
112         printf OUT "# Disc length: %d seconds\n", $total_len / 1000.0;
113         print OUT "#\n";
114         print OUT "# Submitted via: XXXXXX\n";
115         print OUT "#\n";
116         print OUT "#blues,classical,country,data,folk,jazz,newage,reggae,rock,soundtrack,misc\n";
117         print OUT "#CATEGORY=none\n";
118         print OUT "DISCID=" . $discid . "\n";
119         print OUT "DTITLE=" . $a_artist. " / " . $release->title() . "\n";
120         print OUT "DYEAR=\n";
121         print OUT "DGENRE=\n";
122
123         my @tracks = @{$release->track_list()->tracks()};
124         for (my $i = 0; $i < scalar(@tracks); $i++) {
125             my $track = $tracks[$i];
126             my $t_name = $track->title;
127             if ($va) {
128                 my $t_artist = $track->artist->name;
129                 printf OUT "TTITLE%d=%s / %s\n", $i, $t_artist, $t_name;
130             } else {
131                 printf OUT "TTITLE%d=%s\n", $i, $t_name;
132             }
133         }
134
135         print OUT "EXTD=\n";
136         for (my $i = 0; $i < scalar(@tracks); $i++) {
137             printf OUT "EXTT%d=\n", $i;
138         }
139         print OUT "PLAYORDER=\n";
140         print OUT ".\n";
141         close OUT;
142
143         # Check to see that this entry is unique; generate a checksum
144         # and compare to any previous checksums
145         my $checksum = calc_sha1("$workdir/cddbread.$releasenum");
146         foreach my $sum (@sums) {
147             if ($checksum eq $sum) {
148                 unlink("$workdir/cddbread.$releasenum");
149                 $releasenum--;
150                 last;
151             }
152         }
153         push (@sums, $checksum);
154     }
155 } elsif ($command =~ m/calcid/) {
156 # Calculate MusicBrainz ID from disc offsets; see
157 # http://musicbrainz.org/doc/DiscIDCalculation
158
159
160     if ($#discinfo < 5) {
161         print STDERR "Insufficient or missing discinfo data.\n";
162         exit(1);
163     }
164     my ($first, $last, $leadin, $leadout, @offsets) = @discinfo;
165
166     my $s = Digest::SHA->new(1);
167     $s->add(sprintf "%02X", int($first));
168     $s->add(sprintf "%02X", int($last));
169
170     my @a;
171     for (my $i = 0; $i < 100; $i++) {
172         $a[$i] = 0;
173     }
174     my $i = 0;
175     foreach my $o ($leadout, @offsets) {
176        $a[$i++] = int($o) + int($leadin);
177     }
178     for (my $i = 0; $i < 100; $i++) {
179        $s->add(sprintf "%08X", $a[$i]);
180     }
181
182     my $id = $s->b64digest;
183     # CPAN Digest modules do not pad their Base64 output, so we have to do it.
184     while (length($id) % 4) {
185         $id .= '=';
186     }
187
188     $id =~ tr#+#.#;
189     $id =~ tr#/#_#;
190     $id =~ tr#=#-#;
191
192     print $id;
193     if (-t STDOUT) { print "\n"; }
194 } else {
195     print STDERR "Unknown commmand given.\n";
196     pod2usage(1);
197     exit(1);
198 }
199 __END__
200
201 =head1 NAME
202
203 abcde-musicbrainz-tool - Musicbrainz query tool
204
205 =head1 SYNOPSIS
206
207  abcde-musicbrainz-tool [options]
208
209  Options:
210    --command {id|data|calcid} mode of operation (default: id)
211    --device <DEV>             read from CD-ROM device DEV (default: /dev/cdrom)
212    --discid <ID>              Disc ID to query with --command data.
213    --discinfo <F> <L> <LI> <LO> <TRK1OFF> [<TRK2OFF> [...]]
214                               Disc information for --command calcid.
215    --workdir <DIR>            working directory (default: /tmp)
216    --help                     print option summary
217    --man                      full documentation
218
219 =head1 OPTIONS
220
221 =over 8
222
223 =item B<--command> I<{id|data|calcid}>
224
225 Select mode of operation:
226
227 =over 8
228
229 =item B<id>
230
231 Read the disc-ID from the disc in the given device, and print it, the number of tracks, their start sectors, and the duration of the disc in seconds, to stdout. Format:
232
233  ID TRACKCOUNT OFFSET1 [OFFSET2 [...]] LENGTH_S
234
235 =item B<data>
236
237 Query MusicBrainz web service and store data into the workdir into cddbread.1, cddbread.2, ... files in the workdir.
238
239 =item B<calcid>
240
241 Calculate MusicBrainz ID from given B<--discinfo> data.
242
243 =back
244
245 =item B<--device>
246
247 Specify CD-ROM drive's device name, to read ID from with B<--command id>.
248
249 =item B<--discid>
250
251 Supply disc ID for B<--command data>.
252
253 =item B<--discinfo> I<<first track> <last track> <lead-in sector> <lead-out sector> <track1 offset> [<track2 offset> [...]]>
254
255 Supply disc information for B<--command calcid>.
256
257 =item B<--workdir> I<directory>
258
259 The cddbread.* output files from B<--command data> go into this directory.
260
261 =item B<--help>
262
263 Print a brief help message and exit.
264
265 =item B<--man>
266
267 Display full manual and exit.
268
269 =back