6d2c675ce12154faabd2f0165c7a5172a9153acf
[abcde.git] / abcde-musicbrainz-tool
1 #!/usr/bin/perl
2 # Copyright (c) 2012-2018 Steve McIntyre <93sam@debian.org>
3 # This code is hereby licensed for public consumption under either the
4 # GNU GPL v2 or greater, or Larry Wall's Artistic license - your choice.
5 #
6 # You should have received a copy of the GNU General Public License along
7 # with this program; if not, write to the Free Software Foundation, Inc.,
8 # 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
9 #
10 # abcde-musicbrainz-tool
11 #
12 # Helper script for abcde to work with the MusicBrainz WS API (v2)
13
14 use strict;
15 use utf8;
16 use POSIX qw(ceil);
17 use Digest::SHA;
18 use MusicBrainz::DiscID;
19 use WebService::MusicBrainz 1.0.4;
20 use Getopt::Long;
21 use Pod::Usage;
22
23 my $FRAMES_PER_S = 75;
24
25 my ($device, $command, $discid, @discinfo, $workdir, $help, $man, $start);
26 Getopt::Long::Configure ('no_ignore_case');
27 Getopt::Long::Configure ('no_auto_abbrev');
28 GetOptions ("device=s"       => \$device,
29             "command=s"      => \$command,
30             "discid=s"       => \$discid,
31             "discinfo=i{5,}" => \@discinfo,
32             "workdir=s"      => \$workdir,
33             "start=s"        => \$start,
34             "help|h"         => \$help,
35             "man"            => \$man) or pod2usage(-verbose => 0, -exitcode => 2);
36 if (@ARGV) {
37     print STDERR "Extraneous arguments given.\n";
38     pod2usage(-verbose => 0, -exitcode => 2);
39 }
40 pod2usage(-verbose => 1, -exitcode => 0) if $help;
41 pod2usage(-verbose => 2, -exitcode => 0) if $man;
42
43 # defaults
44 if (!defined($device)) {
45     $device = "/dev/cdrom";
46 }
47 if (!defined($command)) {
48     $command = "id";
49 }
50 if (!defined($workdir)) {
51     $workdir = "/tmp";
52 }
53 if (!defined($start)) {
54     $start = "0";
55 }
56
57 sub calc_sha1($) {
58     my $filename = shift;
59     my $s = Digest::SHA->new(1);
60     $s->addfile($filename);
61     return $s->hexdigest;
62 }
63
64 if ($command =~ m/^id/) {
65     my $disc = new MusicBrainz::DiscID($device);
66
67     # read the disc in the default disc drive */
68     if ( $disc->read() == 0 ) {
69         printf STDERR "Error: %s\n", $disc->error_msg();
70         exit(1);
71     }
72
73     printf("%s ", $disc->id());
74     printf("%d ", $disc->last_track_num() + 1 - $disc->first_track_num());
75
76     for ( my $i = $disc->first_track_num;
77           $i <= $disc->last_track_num; $i++ ) {
78         printf("%d ", $disc->track_offset($i));
79     }
80     printf("%d\n", $disc->sectors() / $FRAMES_PER_S);
81     undef $disc;
82 } elsif ($command =~ m/data/) {
83     if (!defined $discid or !$discid) {
84         print STDERR "Discid undefined.\n";
85         exit(1);
86     }
87     my $ws = WebService::MusicBrainz->new();
88     my $response = $ws->search(discid => {
89         discid => $discid,
90         inc => ['artists', 'artist-credits', 'recordings']
91         });
92
93     if ($response->{'error'}) {
94         print STDERR "MusicBrainz lookup returned an error \"$response->{'error'}\"\n";
95         exit(0);
96     }
97
98     my @releases = @{ $response->{'releases'} };
99     my $releasenum = $start;
100     my @sums;
101
102     foreach my $release (@releases) {
103         my $a_artist = "";
104         my $number_artists = @{ $release->{'artist-credit'}};
105         if ($number_artists > 0) {
106             for (my $i = 0; $i < $number_artists; $i++) {
107                 if ($i > 0) {
108                     $a_artist = $a_artist . @{ $release->{'artist-credit'} }[$i-1]->{'joinphrase'};
109                 }
110                 $a_artist = $a_artist . @{ $release->{'artist-credit'} }[$i]->{'name'};
111             }
112         }
113         my $va = 0;
114         my $rel_year = "";
115         if ($a_artist =~ /Various Artists/) {
116             $va = 1;
117         }
118
119         if ($release->{'release-events'}) {
120             my @release_events = @{ $release->{'release-events'} };
121             if (@release_events > 0) {
122                 $rel_year =  substr(@release_events[0]->{'date'},0,4);
123             }
124         }
125         $releasenum++;
126         open (OUT, "> $workdir/cddbread.$releasenum");
127         binmode OUT, ":utf8";
128         print OUT "# xmcd style database file\n";
129         print OUT "#\n";
130         print OUT "# Track frame offsets:\n";
131
132         my @offsets = @{ $response->{'offsets'}};
133         foreach my $offset (@offsets) {
134             printf OUT "#       %d\n", $offset;
135         }
136
137         # Locate the media that contains a disc with the discid we requested
138         # initially. The API may return multiple media associated with the
139         # release, including media with different discids
140         my @mediums = grep {
141             my @disks = @{ $_->{'discs'} };
142             grep { $_->{'id'} eq $discid } @disks;
143         } @{ $release->{'media'} };
144
145         if (not @mediums) {
146             # This release doesn't have a media with our requested dicsid
147             # Shouldn't happen (?), skip it
148             next;
149         }
150
151         # Only consider the first medium
152         my $medium = @mediums[0];
153         my @tracks = @{ $medium->{'tracks'} };
154
155         my $total_len = 0;
156         for (my $i = 0; $i < scalar(@tracks); $i++) {
157             my $track = $tracks[$i];
158             $total_len += $track->{'length'};
159         }
160
161         print OUT "#\n";
162         printf OUT "# Disc length: %d seconds\n", $total_len / 1000.0;
163         print OUT "#\n";
164         print OUT "# Submitted via: XXXXXX\n";
165         print OUT "#\n";
166         print OUT "#blues,classical,country,data,folk,jazz,newage,reggae,rock,soundtrack,misc\n";
167         print OUT "#CATEGORY=none\n";
168         print OUT "DISCID=" . $discid . "\n";
169         print OUT "DTITLE=" . $a_artist. " / " . $release->{'title'} . "\n";
170         print OUT "DYEAR=" . $rel_year . "\n";
171         print OUT "DGENRE=\n";        
172
173         for (my $i = 0; $i < scalar(@tracks); $i++) {
174             my $track = $tracks[$i];
175             my $t_name = $track->{'title'};
176             my $number_artists = @{$track->{'recording'}->{'artist-credit'}};
177             if ($va and $number_artists > 0) {
178                 my $t_artist = "";
179                 for (my $j = 0; $j < $number_artists; $j++) {
180                     if ($j > 0) {
181                         $t_artist = $t_artist . @{$track->{'recording'}->{'artist-credit'}}[$j-1]->{'joinphrase'};
182                     }
183                     $t_artist = $t_artist . @{$track->{'recording'}->{'artist-credit'}}[$j]->{'name'};
184                 }
185                 printf OUT "TTITLE%d=%s / %s\n", $i, $t_artist, $t_name;
186             } else {
187                 printf OUT "TTITLE%d=%s\n", $i, $t_name;
188             }
189         }
190
191         print OUT "EXTD=\n";
192         for (my $i = 0; $i < scalar(@tracks); $i++) {
193             printf OUT "EXTT%d=\n", $i;
194         }
195         print OUT "PLAYORDER=\n";
196         print OUT ".\n";
197         close OUT;
198
199         # save release mbid
200         open (OUT, "> $workdir/mbid.$releasenum");
201         print OUT $release->{'id'};
202         close OUT;
203
204         # save release asin
205         open (OUT, "> $workdir/asin.$releasenum");
206         print OUT $release->{'asin'};
207         close OUT;
208
209         # Check to see that this entry is unique; generate a checksum
210         # and compare to any previous checksums
211         my $checksum = calc_sha1("$workdir/cddbread.$releasenum");
212         foreach my $sum (@sums) {
213             if ($checksum eq $sum) {
214                 unlink("$workdir/cddbread.$releasenum");
215                 $releasenum--;
216                 last;
217             }
218         }
219         push (@sums, $checksum);
220     }
221 } elsif ($command =~ m/calcid/) {
222     # Calculate MusicBrainz ID from disc offsets; see
223     # https://musicbrainz.org/doc/DiscIDCalculation
224
225     if ($#discinfo < 5) {
226         print STDERR "Insufficient or missing discinfo data.\n";
227         exit(1);
228     }
229     my ($first, $last, $leadin, $leadout, @offsets) = @discinfo;
230
231     my $s = Digest::SHA->new(1);
232     $s->add(sprintf "%02X", int($first));
233     $s->add(sprintf "%02X", int($last));
234
235     my @a;
236     for (my $i = 0; $i < 100; $i++) {
237         $a[$i] = 0;
238     }
239     my $i = 0;
240     foreach my $o ($leadout, @offsets) {
241        $a[$i++] = int($o) + int($leadin);
242     }
243     for (my $i = 0; $i < 100; $i++) {
244        $s->add(sprintf "%08X", $a[$i]);
245     }
246
247     my $id = $s->b64digest;
248     # CPAN Digest modules do not pad their Base64 output, so we have to do it.
249     while (length($id) % 4) {
250         $id .= '=';
251     }
252
253     $id =~ tr#+#.#;
254     $id =~ tr#/#_#;
255     $id =~ tr#=#-#;
256
257     print $id;
258     if (-t STDOUT) { print "\n"; }
259 } else {
260     print STDERR "Unknown command given.\n";
261     pod2usage(1);
262     exit(1);
263 }
264 __END__
265
266 =head1 NAME
267
268 abcde-musicbrainz-tool - Musicbrainz query tool
269
270 =head1 SYNOPSIS
271
272  abcde-musicbrainz-tool [options]
273
274  Options:
275    --command {id|data|calcid} mode of operation (default: id)
276    --device <DEV>             read from CD-ROM device DEV (default: /dev/cdrom)
277    --discid <ID>              Disc ID to query with --command data.
278    --discinfo <F> <L> <LI> <LO> <TRK1OFF> [<TRK2OFF> [...]]
279                               Disc information for --command calcid.
280    --workdir <DIR>            working directory (default: /tmp)
281    --help                     print option summary
282    --man                      full documentation
283
284 =head1 OPTIONS
285
286 =over 8
287
288 =item B<--command> I<{id|data|calcid}>
289
290 Select mode of operation:
291
292 =over 8
293
294 =item B<id>
295
296 Read the disc-ID from the disc in the given device, and print it, the number of tracks, their start sectors, and the duration of the disc in seconds, to stdout. Format:
297
298  ID TRACKCOUNT OFFSET1 [OFFSET2 [...]] LENGTH_S
299
300 =item B<data>
301
302 Query MusicBrainz web service and store data into the workdir into cddbread.1, cddbread.2, ... files in the workdir.
303
304 =item B<calcid>
305
306 Calculate MusicBrainz ID from given B<--discinfo> data.
307
308 =back
309
310 =item B<--device>
311
312 Specify CD-ROM drive's device name, to read ID from with B<--command id>.
313
314 =item B<--discid>
315
316 Supply disc ID for B<--command data>.
317
318 =item B<--discinfo> I<<first track> <last track> <lead-in sector> <lead-out sector> <track1 offset> [<track2 offset> [...]]>
319
320 Supply disc information for B<--command calcid>.
321
322 =item B<--workdir> I<directory>
323
324 The cddbread.* output files from B<--command data> go into this directory.
325
326 =item B<--help>
327
328 Print a brief help message and exit.
329
330 =item B<--man>
331
332 Display full manual and exit.
333
334 =back